返回首頁
當前位置: 主頁 > 操作系統 > Linux教程 >

STM32啟動文件詳解

時間:2015-07-17 10:19來源:電腦教程學習網 www.aedwey.tw 編輯:admin

在嵌入式應用程序開發過程里,由于使用C語言編程,基本很少涉及到機器底層寄存器的執行過程,一般都會直接在main函數里開始寫代碼,似乎main成為了理所當然的起點,盡管從C程序的角度來看程序都是直接從main函數開始執行。然而,MCU上電后,是如何尋找到并執行main函數這一問題卻很自然的被忽略了!事實上微控制器是無法從硬件上去定位main函數的入口地址,因為使用C語言作為開發語言后,變量/函數的地址便由編譯器在編譯時自行分配,因此main函數的入口地址在編譯后便不一定是一個絕對地址。MCU上電后又是如何尋找到這個入口地址呢?以前接觸無論是PIC、AVR、MSP430或是51過程中都沒涉及到啟動文件的配置,僅僅只有熔絲位或配置字是需要根據實際使用配置來設置,其實并非沒有,而是由于大部分的開發環境往往自動完整地提供了這個啟動文件,不需要開發人員再行干預啟動過程,只需要從main函數開始進行應用程序的設計即可。然而,但接觸到嵌入內核比如Linux系統移植過程“bootloader”卻是很重要也是必不可少的一個環節。事實上,每一種微控制器,無論性能高下,結構簡繁,價格貴賤都是必須有啟動文件才能正常工作的,它的作用同“bootloader”類似。啟動文件完成了微控制器從“復位”到“開始執行main函數”中間這段時間的必要啟動配置。

在STM32中,如果是在MDK下創建一個工程,一般都有提示是否加入Star up Code文件,這個就是啟動文件,這里有個誤區,一般對于初學者來看,很容易誤以為STM32F10x.s這個啟動文件是STM32所有類型芯片的通用啟動文件,因此也自然不會去理會它的作用,事實上,這個啟動文件只是針對部分STM32系列,如果仔細看過它的啟動代碼就會發現里面很多中斷函數定義是沒有的,甚至有些和STM32F10x_it.c里的函數是有出路的,如果剛好用到了默認的這個中斷服務子函數的話,程序一旦運行到了中斷是找不到入口地址的,這樣就會莫名其妙地不知問題所在。STM32F10x.s是MDK提供的啟動代碼,從其里面的內容看來,它只定義了3個串口,4個定時器。實際上STM32的系列產品有5個串口的型號,也只有有2個串口的型號,定時器也是,做多的有8個定時器。比如,如果你用的STM32F103ZET6,而啟動文件用的是STM32F10x.s的話,你可以正常使用串口1~3的中斷,而串口4和5的中斷,則無法正常使用。所以STM32F10x.s并不能適用所有的STM32型號,對于不同型號的STM32,正確做法是選擇不同的啟動文件。ST公司提供了3個啟動文件:

startup_stm32f10x_ld.s

startup_stm32f10x_md.s

startup_stm32f10x_hd.s

分別適用于小容量/中容量/大容量的STM32芯片,具體判斷方法如下:

小容量:FLASH≤32K
中容量:64K≤FLASH≤128K
大容量:256K≤FLASH
在啟動代碼中,補充幾點:

啟動代碼中的兩條語句解釋:

一、PROC 為子程序開始,ENDP 為子程序結束

二、[weak] 的意思是該函數優先級比較弱,如果其它地方定義了一個同名函數,那么此處的這個函數就被取代了。語法格式為 EXPORT 標號 {[WEAK]} 。EXPORT 可用GLOBAL代替。

對于_main函數的理解:

事實上,_main 和main是兩個完全不同的函數!_main代碼是編譯器自動創建的,因此無法找到_main代碼。MDK文檔中有一句說明:it is automatically craated by the linker when it sees a definition of main() .大體意思可以理解為:當編譯器發現定義了main函數,那么就會自動創建_main.

_main 和main的關系

_main 主要做兩件事:其一,C所需的資源;其二,調用main函數。這就不難理解為什么在啟動代碼調用的是_main ,最后卻能轉到main函數中去執行的原因了。

 

AREA指令的理解

AREA指令是一個偽指令,用于段定義。ARM匯編程序由段組成,段是相對獨立的指令或數據單位,每個段由AREA偽指令定義,并定義段的屬性。

AREA參數說明:

* STACK——AREA指令的一個參數,定義段名稱

* NOINIT——AREA指令的一個參數,指定本數據段僅僅保留了內在單元,而將句初始值寫入內存單元,此時內存單元值初始化為0

* READWRITE——指定本段為可讀可寫,數據段默認為READWRITE.

READWRITE(讀寫)、READONLY(只讀)

* ALIGN——也是一個偽指令,指定對齊方式。ALIGN n 指令的對齊值有兩種選擇:n或者2^n

例子:開辟一個堆棧段,段名為STACK,定義為可讀可寫,將內存單元初始化為0,對齊方式為8字節對齊。

AREA STACK,NOINIT,READWRITE,ALIGN=3

STM32啟動文件詳解
 

相對于ARM上一代的主流ARM7/ARM9內核架構,新一代Cortex內核架構的啟動方式有了比較大的變化。ARM7/ARM9內核的控制器在復位后,CPU會從存儲空間的絕對地址0x000000取出第一條指令執行復位中斷服務程序的方式啟動,即固定了復位后的起始地址為0x000000(PC = 0x000000)同時中斷向量表的位置并不是固定的。而Cortex-M3內核則正好相反,有3種情況:

1、 通過boot引腳設置可以將中斷向量表定位于SRAM區,即起始地址為0x2000000,同時復位后PC指針位于0x2000000處;

2、 通過boot引腳設置可以將中斷向量表定位于FLASH區,即起始地址為0x8000000,同時復位后PC指針位于0x8000000處;

3、 通過boot引腳設置可以將中斷向量表定位于內置Bootloader區,本文不對這種情況做論述;

而Cortex-M3內核規定,起始地址必須存放堆頂指針,而第二個地址則必須存放復位中斷入口向量地址,這樣在Cortex-M3內核復位后,會自動從起始地址的下一個32位空間取出復位中斷入口向量,跳轉執行復位中斷服務程序。對比ARM7/ARM9內核,Cortex-M3內核則是固定了中斷向量表的位置而起始地址是可變化的。
有了上述準備只是后,下面以STM32的2.02固件庫提供的啟動文件“stm32f10x_vector.s”為模板,對STM32的啟動過程做一個簡要而全面的解析。

程序清單一:
文件“stm32f10x_vector.s”,其中注釋為行號

DATA_IN_ExtSRAM EQU 0 ;1
Stack_Size EQU 0x00000400 ;2
AREA STACK, NOINIT, READWRITE, ALIGN = 3 ;3
Stack_Mem SPACE Stack_Size ;4
__initial_sp ;5
Heap_Size EQU 0x00000400 ;6
AREA HEAP, NOINIT, READWRITE, ALIGN = 3 ;7
__heap_base ;8
Heap_Mem SPACE Heap_Size ;9
__heap_limit ;10
THUMB ;11
PRESERVE8 ;12
IMPORT NMIException ;13
IMPORT HardFaultException ;14
IMPORT MemManageException ;15
IMPORT BusFaultException ;16
IMPORT UsageFaultException ;17
IMPORT SVCHandler ;18
IMPORT DebugMonitor ;19
IMPORT PendSVC ;20
IMPORT SysTickHandler ;21
IMPORT WWDG_IRQHandler ;22
IMPORT PVD_IRQHandler ;23
IMPORT TAMPER_IRQHandler ;24
IMPORT RTC_IRQHandler ;25
IMPORT FLASH_IRQHandler ;26
IMPORT RCC_IRQHandler ;27
IMPORT EXTI0_IRQHandler ;28
IMPORT EXTI1_IRQHandler ;29
IMPORT EXTI2_IRQHandler ;30
IMPORT EXTI3_IRQHandler ;31
IMPORT EXTI4_IRQHandler ;32
IMPORT DMA1_Channel1_IRQHandler ;33
IMPORT DMA1_Channel2_IRQHandler ;34
IMPORT DMA1_Channel3_IRQHandler ;35
IMPORT DMA1_Channel4_IRQHandler ;36
IMPORT DMA1_Channel5_IRQHandler ;37
IMPORT DMA1_Channel6_IRQHandler ;38
IMPORT DMA1_Channel7_IRQHandler ;39
IMPORT ADC1_2_IRQHandler ;40
IMPORT USB_HP_CAN_TX_IRQHandler ;41
IMPORT USB_LP_CAN_RX0_IRQHandler ;42
IMPORT CAN_RX1_IRQHandler ;43
IMPORT CAN_SCE_IRQHandler ;44
IMPORT EXTI9_5_IRQHandler ;45
IMPORT TIM1_BRK_IRQHandler ;46
IMPORT TIM1_UP_IRQHandler ;47
IMPORT TIM1_TRG_COM_IRQHandler ;48
IMPORT TIM1_CC_IRQHandler ;49
IMPORT TIM2_IRQHandler ;50
IMPORT TIM3_IRQHandler ;51
IMPORT TIM4_IRQHandler ;52
IMPORT I2C1_EV_IRQHandler ;53
IMPORT I2C1_ER_IRQHandler ;54
IMPORT I2C2_EV_IRQHandler ;55
IMPORT I2C2_ER_IRQHandler ;56
IMPORT SPI1_IRQHandler ;57
IMPORT SPI2_IRQHandler ;58
IMPORT USART1_IRQHandler ;59
IMPORT USART2_IRQHandler ;60
IMPORT USART3_IRQHandler ;61
IMPORT EXTI15_10_IRQHandler ;62
IMPORT RTCAlarm_IRQHandler ;63
IMPORT USBWakeUp_IRQHandler ;64
IMPORT TIM8_BRK_IRQHandler ;65
IMPORT TIM8_UP_IRQHandler ;66
IMPORT TIM8_TRG_COM_IRQHandler ;67
IMPORT TIM8_CC_IRQHandler ;68
IMPORT ADC3_IRQHandler ;69
IMPORT FSMC_IRQHandler ;70
IMPORT SDIO_IRQHandler ;71
IMPORT TIM5_IRQHandler ;72
IMPORT SPI3_IRQHandler ;73
IMPORT UART4_IRQHandler ;74
IMPORT UART5_IRQHandler ;75
IMPORT TIM6_IRQHandler ;76
IMPORT TIM7_IRQHandler ;77
IMPORT DMA2_Channel1_IRQHandler ;78
IMPORT DMA2_Channel2_IRQHandler ;79
IMPORT DMA2_Channel3_IRQHandler ;80
IMPORT DMA2_Channel4_5_IRQHandler ;81
AREA RESET, DATA, READONLY ;82
EXPORT __Vectors ;83
__Vectors ;84
DCD __initial_sp ;85
DCD Reset_Handler ;86
DCD NMIException ;87
DCD HardFaultException ;88
DCD MemManageException ;89
DCD BusFaultException ;90
DCD UsageFaultException ;91
DCD 0 ;92
DCD 0 ;93
DCD 0 ;94
DCD 0 ;95
DCD SVCHandler ;96
DCD DebugMonitor ;97
DCD 0 ;98
DCD PendSVC ;99
DCD SysTickHandler ;100
DCD WWDG_IRQHandler ;101
DCD PVD_IRQHandler ;102
DCD TAMPER_IRQHandler ;103
DCD RTC_IRQHandler ;104
DCD FLASH_IRQHandler ;105
DCD RCC_IRQHandler ;106
DCD EXTI0_IRQHandler ;107
DCD EXTI1_IRQHandler ;108
DCD EXTI2_IRQHandler ;109
DCD EXTI3_IRQHandler ;110
DCD EXTI4_IRQHandler ;111
DCD DMA1_Channel1_IRQHandler ;112
DCD DMA1_Channel2_IRQHandler ;113
DCD DMA1_Channel3_IRQHandler ;114
DCD DMA1_Channel4_IRQHandler ;115
DCD DMA1_Channel5_IRQHandler ;116
DCD DMA1_Channel6_IRQHandler ;117
DCD DMA1_Channel7_IRQHandler ;118
DCD ADC1_2_IRQHandler ;119
DCD USB_HP_CAN_TX_IRQHandler ;120
DCD USB_LP_CAN_RX0_IRQHandler ;121
DCD CAN_RX1_IRQHandler ;122
DCD CAN_SCE_IRQHandler ;123
DCD EXTI9_5_IRQHandler ;124
DCD TIM1_BRK_IRQHandler ;125
DCD TIM1_UP_IRQHandler ;126
DCD TIM1_TRG_COM_IRQHandler ;127
DCD TIM1_CC_IRQHandler ;128
DCD TIM2_IRQHandler ;129
DCD TIM3_IRQHandler ;130
DCD TIM4_IRQHandler ;131
DCD I2C1_EV_IRQHandler ;132
DCD I2C1_ER_IRQHandler ;133
DCD I2C2_EV_IRQHandler ;134
DCD I2C2_ER_IRQHandler ;135
DCD SPI1_IRQHandler ;136
DCD SPI2_IRQHandler ;137
DCD USART1_IRQHandler ;138
DCD USART2_IRQHandler ;139
DCD USART3_IRQHandler ;140
DCD EXTI15_10_IRQHandler ;141
DCD RTCAlarm_IRQHandler ;142
DCD USBWakeUp_IRQHandler ;143
DCD TIM8_BRK_IRQHandler ;144
DCD TIM8_UP_IRQHandler ;145
DCD TIM8_TRG_COM_IRQHandler ;146
DCD TIM8_CC_IRQHandler ;147
DCD ADC3_IRQHandler ;148
DCD FSMC_IRQHandler ;149
DCD SDIO_IRQHandler ;150
DCD TIM5_IRQHandler ;151
DCD SPI3_IRQHandler ;152
DCD UART4_IRQHandler ;153
DCD UART5_IRQHandler ;154
DCD TIM6_IRQHandler ;155
DCD TIM7_IRQHandler ;156
DCD DMA2_Channel1_IRQHandler ;157
DCD DMA2_Channel2_IRQHandler ;158
DCD DMA2_Channel3_IRQHandler ;159
DCD DMA2_Channel4_5_IRQHandler ;160
AREA |.text|, CODE, READONLY ;161
Reset_Handler PROC ;162
EXPORT Reset_Handler ;163
IF DATA_IN_ExtSRAM == 1 ;164
LDR R0,= 0x00000114 ;165
LDR R1,= 0x40021014 ;166
STR R0,[R1] ;167
LDR R0,= 0x000001E0 ;168
LDR R1,= 0x40021018 ;169
STR R0,[R1] ;170
LDR R0,= 0x44BB44BB ;171
LDR R1,= 0x40011400 ;172
STR R0,[R1] ;173
LDR R0,= 0xBBBBBBBB ;174
LDR R1,= 0x40011404 ;175
STR R0,[R1] ;176
LDR R0,= 0xB44444BB ;177
LDR R1,= 0x40011800 ;178
STR R0,[R1] ;179
LDR R0,= 0xBBBBBBBB ;180
LDR R1,= 0x40011804 ;181
STR R0,[R1] ;182
LDR R0,= 0x44BBBBBB ;183
LDR R1,= 0x40011C00 ;184
STR R0,[R1] ;185
LDR R0,= 0xBBBB4444 ;186
LDR R1,= 0x40011C04 ;187
STR R0,[R1] ;188
LDR R0,= 0x44BBBBBB ;189
LDR R1,= 0x40012000 ;190
STR R0,[R1] ;191
LDR R0,= 0x44444B44 ;192
LDR R1,= 0x40012004 ;193
STR R0,[R1] ;194
LDR R0,= 0x00001011 ;195
LDR R1,= 0xA0000010 ;196
STR R0,[R1] ;197
LDR R0,= 0x00000200 ;198
LDR R1,= 0xA0000014 ;199
STR R0,[R1] ;200
ENDIF ;201
IMPORT __main ;202
LDR R0, =__main ;203
BX R0 ;204
ENDP ;205
ALIGN ;206
IF : DEF:__MICROLIB ;207
EXPORT __initial_sp ;208
EXPORT __heap_base ;209
EXPORT __heap_limit ;210
ELSE ;211
IMPORT __use_two_region_memory ;212
EXPORT __user_initial_stackheap ;213
__user_initial_stackheap ;214
LDR R0, = Heap_Mem ;215
LDR R1, = (Stack_Mem + Stack_Size) ;216
LDR R2, = (Heap_Mem + Heap_Size) ;217
LDR R3, = Stack_Mem ;218
BX LR ;219
ALIGN ;220
ENDIF ;221
END ;222
ENDIF ;223
END ;224

如程序清單一,STM32的啟動代碼一共224行,使用了匯編語言編寫,這其中的主要原因下文將會給出交代。現在從第一行開始分析:
第1行:定義是否使用外部SRAM,為1則使用,為0則表示不使用。此語行若用C語言表達則等價于:
#define DATA_IN_ExtSRAM 0
第2行:定義棧空間大小為0x00000400個字節,即1Kbyte。此語行亦等價于:
#define Stack_Size 0x00000400
第3行:偽指令AREA,表示
第4行:開辟一段大小為Stack_Size的內存空間作為棧。
第5行:標號__initial_sp,表示棧空間頂地址。
第6行:定義堆空間大小為0x00000400個字節,也為1Kbyte。
第7行:偽指令AREA,表示
第8行:標號__heap_base,表示堆空間起始地址。
第9行:開辟一段大小為Heap_Size的內存空間作為堆。
第10行:標號__heap_limit,表示堆空間結束地址。
第11行:告訴編譯器使用THUMB指令集。
第12行:告訴編譯器以8字節對齊。
第13—81行:IMPORT指令,指示后續符號是在外部文件定義的(類似C語言中的全局變量聲明),而下文可能會使用到這些符號。
第82行:定義只讀數據段,實際上是在CODE區(假設STM32從FLASH啟動,則此中斷向量表起始地址即為0x8000000)
第83行:將標號__Vectors聲明為全局標號,這樣外部文件就可以使用這個標號。
第84行:標號__Vectors,表示中斷向量表入口地址。
第85—160行:建立中斷向量表。
第161行:
第162行:復位中斷服務程序,PROC…ENDP結構表示程序的開始和結束。
第163行:聲明復位中斷向量Reset_Handler為全局屬性,這樣外部文件就可以調用此復位中斷服務。
第164行:IF…ENDIF為預編譯結構,判斷是否使用外部SRAM,在第1行中已定義為“不使用”。
第165—201行:此部分代碼的作用是設置FSMC總線以支持SRAM,因不使用外部SRAM因此此部分代碼不會被編譯。
第202行:聲明__main標號。
第203—204行:跳轉__main地址執行。
第207行:IF…ELSE…ENDIF結構,判斷是否使用DEF:__MICROLIB(此處為不使用)。
第208—210行:若使用DEF:__MICROLIB,則將__initial_sp,__heap_base,__heap_limit亦即棧頂地址,堆始末地址賦予全局屬性,使外部程序可以使用。
第212行:定義全局標號__use_two_region_memory。
第213行:聲明全局標號__user_initial_stackheap,這樣外程序也可調用此標號。
第214行:標號__user_initial_stackheap,表示用戶堆棧初始化程序入口。
第215—218行:分別保存棧頂指針和棧大小,堆始地址和堆大小至R0,R1,R2,R3寄存器。
第224行:程序完畢。

以上便是STM32的啟動代碼的完整解析,接下來對幾個小地方做解釋:

1、 AREA指令:偽指令,用于定義代碼段或數據段,后跟屬性標號。其中比較重要的一個標號為“READONLY”或者“READWRITE”,其中“READONLY”表示該段為只讀屬性,聯系到STM32的內部存儲介質,可知具有只讀屬性的段保存于FLASH區,即0x8000000地址后。而“READWRITE”表示該段為“可讀寫”屬性,可知“可讀寫”段保存于SRAM區,即0x2000000地址后。由此可以從第3、7行代碼知道,堆棧段位于SRAM空間。從第82行可知,中斷向量表放置與FLASH區,而這也是整片啟動代碼中最先被放進FLASH區的數據。因此可以得到一條重要的信息:0x8000000地址存放的是棧頂地址__initial_sp,0x8000004地址存放的是復位中斷向量Reset_Handler(STM32使用32位總線,因此存儲空間為4字節對齊)。

2、 DCD指令:作用是開辟一段空間,其意義等價于C語言中的地址符“&”。因此從第84行開始建立的中斷向量表則類似于使用C語言定義了一個指針數組,其每一個成員都是一個函數指針,分別指向各個中斷服務函數。

3、 標號:前文多處使用了“標號”一詞。標號主要用于表示一片內存空間的某個位置,等價于C語言中的“地址”概念。地址僅僅表示存儲空間的一個位置,從C語言的角度來看,變量的地址,數組的地址或是函數的入口地址在本質上并無區別。

4、 第202行中的__main標號并不表示C程序中的main函數入口地址,因此第204行也并不是跳轉至main函數開始執行C程序。__main標號表示C/C++標準實時庫函數里的一個初始化子程序__main的入口地址。該程序的一個主要作用是初始化堆棧(對于程序清單一來說則是跳轉__user_initial_stackheap標號進行初始化堆棧的),并初始化映像文件,最后跳轉C程序中的main函數。這就解釋了為何所有的C程序必須有一個main函數作為程序的起點——因為這是由C/C++標準實時庫所規定的——并且不能更改,因為C/C++標準實時庫并不對外界開放源代碼。因此,實際上在用戶可見的前提下,程序在第204行后就跳轉至.c文件中的main函數,開始執行C程序了。

至此可以總結一下STM32的啟動文件和啟動過程。首先對棧和堆的大小進行定義,并在代碼區的起始處建立中斷向量表,其第一個表項是棧頂地址,第二個表項是復位中斷服務入口地址。然后在復位中斷服務程序中跳轉;C/C++標準實時庫的__main函數,完成用戶堆棧等的初始化后,跳轉.c文件中的main函數開始執行C程序。假設STM32被設置為從內部FLASH啟動(這也是最常見的一種情況),中斷向量表起始地位為0x8000000,則棧頂地址存放于0x8000000處,而復位中斷服務入口地址存放于0x8000004處。當STM32遇到復位信號后,則從0x80000004處取出復位中斷服務入口地址,繼而執行復位中斷服務程序,然后跳轉__main函數,最后進入mian函數,來到C的世界。

------分隔線----------------------------
標簽(Tag):STM32啟動文件
------分隔線----------------------------
推薦內容
猜你感興趣
26选5中奖通告